Path: news.eternal-september.org!eternal-september.org!.POSTED!not-for-mail
From: Stephen Hoffman <seaohveh@hoffmanlabs.invalid>
Newsgroups: comp.os.vms
Subject: Re: Upcoming time boundary events
Date: Sat, 14 Jun 2025 13:00:29 -0400
Organization: HoffmanLabs LLC
Lines: 125
Message-ID: <102k9rd$abd3$1@dont-email.me>
References: <100omli$3t023$1@dont-email.me> <100qdop$6q13$1@dont-email.me> <100qg5t$3jb0$1@dont-email.me> <1014ad8$2jurh$1@dont-email.me> <m9pqvoFnrcsU1@mid.individual.net> <874ix3np14.fsf@atr2.ath.cx> <m9sc6fFnrcsU2@mid.individual.net> <mn.f24a7e95dd606c32.104627@invalid.skynet.be> <101cbrq$gbr1$2@dont-email.me> <mn.fad87e9512caa697.104627@invalid.skynet.be> <101ffbn$1b0s5$1@dont-email.me> <101flk5$12l3d$1@dont-email.me> <683b5cee$0$684$14726298@news.sunsite.dk> <683ce1f4$0$693$14726298@news.sunsite.dk>
MIME-Version: 1.0
Content-Type: text/plain; charset=iso-8859-1; format=flowed
Content-Transfer-Encoding: 8bit
Injection-Date: Sat, 14 Jun 2025 19:00:31 +0200 (CEST)
Injection-Info: dont-email.me; posting-host="b00a2188ad11139c587d140ffdd02b54";
	logging-data="339363"; mail-complaints-to="abuse@eternal-september.org";	posting-account="U2FsdGVkX1/fVKkO8vIy3DkUjB2bcP8TzLROmvd3Eeg="
User-Agent: Unison/2.2
Cancel-Lock: sha1:SyU2VsqRfqdmlfmluaRvMg3pOyY=

On 2025-06-01 23:27:48 +0000, Arne Vajhøj said:

> On 5/31/2025 3:47 PM, Arne Vajhøj wrote:
>> The context was:
>> 
>> ####                                                 and
>> #### transparent task to task communication ?
>> 
>> ### and task to task->INETD.
>> 
>> So I assume that we are talking about how to rewrite
>> something like:
>> 
>> $ open/read f 0::"task=something"
>> $ read f line
>> $ close f
>> $ exit
> 
> Or to provide a complete example:
> 
> $ typ add.com
> $ open/read/write f sys$net
> $ read f num1
> $ num1 = f$integer(num1)
> $ read f num2
> $ num2 = f$integer(num2)
> $ numres = num1 + num2
> $ numres = f$string(numres)
> $ write f numres
> $ close f
> $ exit
> $ typ tst.com
> $ open/read/write f 0"myusername mypassword"::"task=add.com"
> $ write f "123"
> $ write f "456"
> $ read f res
> $ close f
> $ write sys$output res
> $ exit
> $ @tst
> 579
> 
> Arne

From the OpenVMS Freeware...

$!  XQTYPE.COM
$!
$   Set NoOn
$   Set NoVerif
$   vers = "0000|XQTYPE"
$   Goto 'F$Mode()'
$!
$!  ©1989 Digital Equipment Corporation
$!  Written: S Hoffman, 21-Jan-1989
$!
$!  Uses DCL DECnet task-to-task to check the device type of the XQA0:
$!  controller on the remote system.  Can return <unknown>, <none>,
$!  <DELQA> or <DEQNA>.  Requires VMS V5.0 or better as the procedure
$!  uses block-structured IF DCL syntax.
$!
$!  Calling:
$!	@XQTYPE node
$!
$!  Procedure must be named XQTYPE.COM and must reside in the default
$!  login directory on both the local and the remote nodes.  Note that
$!  the remote login may occur either in the directory specified by a
$!  proxy, if one exists, or in the DECNET directory.  If you're not
$!  sure the default directory can be found by entering the command
$!  "DIRECTORY node::".  Requires access to the DECNET TASK object on
$!  the remote end; either by the default DECNET username/password or
$!  via a proxy.
$!
$INTERACTIVE:
$DO_P1:
$   p1 = F$Edit(p1,"COLLAPSE,UPCASE") - "::"
$   If F$Leng(p1) .eq. 0
$   Then
$	msg = "Error reading input"
$	Read/Prompt="Node? "/Error=DONE Sys$Command p1
$	Goto DO_P1
$   EndIf
$!
$   msg = "Error creating network connection"
$   Open/Read/Write/Error=DONE net 'p1'::"task=XQTYPE"
$   Read net remvers
$   Write net vers
$   Read net XQType
$   Close net
$   Write Sys$Output "XQA0: Device type on node ''p1':: is ''XQType'"
$   msg = ""
$   Goto DONE
$
$NETWORK:
$!  remove the colons to work around a FT bug in DECwindows
$   Show Process/All
$   msg = "Error receiving network connection"
$   Open/Read/Write/Error=DONE net Sys$Net
$   Write net vers
$   Read net remvers
$   If F$GetDVI("XQA0:","EXISTS")
$   Then
$	DEVType = F$GetDVI("XQA0:","DEVTYPE")
$	XQType = "<unknown>"
$	If DEVType .eq. 33 Then XQType = "DELQA"
$	If DEVType .eq. 22 Then XQType = "DEQNA"
$   Else
$	XQType = "<none>"
$   EndIf
$   Write net XQType
$   Close net
$
$BATCH:
$OTHER:
$   msg = "Unsupported F$MODE()"
$
$DONE:
$   If F$Len(msg) .ne. 0 Then Write Sys$Output msg
$   Stop
$   Exit


-- 
Pure Personal Opinion | HoffmanLabs LLC